; Script generated by the Inno Setup Script Wizard.
; SEE THE DOCUMENTATION FOR DETAILS ON CREATING INNO SETUP SCRIPT FILES!

#define MyAppName "Shader Wars"
#define MyAppVerName "Shader Wars 1.0"
#define MyAppPublisher "Darkwynter"
#define MyAppURL "http://darkwynter.com"
#define MyAppExeName "ElementalGame.exe"

[Setup]
AppName={#MyAppName}
AppVerName={#MyAppVerName}
AppPublisher={#MyAppPublisher}
AppPublisherURL={#MyAppURL}
AppSupportURL={#MyAppURL}
AppUpdatesURL={#MyAppURL}
DefaultDirName={pf}\ShaderWars
DefaultGroupName={#MyAppName}
AllowNoIcons=true
OutputDir=F:\Documents and Settings\flatline\Desktop\Darkwynter\ShaderWars\bin\x86
OutputBaseFilename=setup
SetupIconFile=F:\Documents and Settings\flatline\Desktop\Darkwynter\ShaderWars\Game.ico
;Password=darkwynter
Encryption=false
Compression=zip
SolidCompression=true
AppCopyright=darkwynter studios
InternalCompressLevel=ultra

[Languages]
Name: english; MessagesFile: compiler:Default.isl

[Tasks]

[Files]
Source: dotnetfx.exe; DestDir: {tmp}; Components: DotNet2
Source: dxwebsetup.exe; DestDir: {tmp}; Components: DX
Source: xnafx_redist.msi; DestDir: {tmp}; Components: XNA
Source: Release\ElementalGame.exe; DestDir: {app}; Flags: ignoreversion; Components: Base
Source: Release\*; DestDir: {app}; Flags: ignoreversion recursesubdirs createallsubdirs; Components: Base
; NOTE: Don't use "Flags: ignoreversion" on any shared system files

[Icons]
Name: {group}\{#MyAppName}; Filename: {app}\{#MyAppExeName}
Name: {group}\{cm:ProgramOnTheWeb,{#MyAppName}}; Filename: {#MyAppURL}
Name: {group}\{cm:UninstallProgram,{#MyAppName}}; Filename: {uninstallexe}

; Having problems with this not setting the Windows Shortcut "Start In" property
; Instead, we just open the install folder
;Name: {commondesktop}\{#MyAppName}; Filename: {app}\{#MyAppExeName}
;Name: {userappdata}\Microsoft\Internet Explorer\Quick Launch\{#MyAppName}; Filename: {app}\{#MyAppExeName}

[Run]
Filename: {tmp}\dotnetfx.exe; Components: DotNet2; Check: NeedDotNet; WorkingDir: {tmp}
Filename: {tmp}\dxwebsetup.exe; Components: DX; Check: NeedDX9c; WorkingDir: {tmp}
Filename: msiexec.exe; Parameters: /i {tmp}\xnafx_redist.msi; Components: XNA; Check: NeedXNA; WorkingDir: {tmp}
Filename: explorer.exe; Parameters: {app}; Components: Base; WorkingDir: {tmp}
Filename: {app}\{#MyAppExeName}; Description: {cm:LaunchProgram,{#MyAppName}}; Flags: nowait postinstall skipifsilent; Components: Base


[Components]
Name: DotNet2; Description: DotNet2; Types: custom compact full; Check: NeedDotNet; Flags: fixed
Name: DX; Description: DX; Types: custom compact full; Check: NeedDX9c; Flags: fixed
Name: XNA; Description: XNA; Types: custom compact full; Check: NeedXNA; Flags: fixed restart
Name: Base; Description: Base; Flags: fixed; Types: custom compact full

[Code]
// Install .Net 2.0?
function NeedDotNet(): Boolean;

begin
	// Check registry to see if .Net 2.0 is installed
	if RegKeyExists(HKEY_LOCAL_MACHINE, 'SOFTWARE\Microsoft\.NETFramework\policy\v2.0')then begin
		Result := False;
	end
	else begin
		Result := True;
	end;
end;


// Install DX9c?
function NeedDX9c(): Boolean;

var
	DXVersion : String;

begin
	// Check registry to see if DX is installed
	//if RegKeyExists(HKEY_LOCAL_MACHINE, 'SOFTWARE\Microsoft\DirectX') then begin

		// Check Version
		//RegQueryStringValue(HKEY_LOCAL_MACHINE, 'SOFTWARE\Microsoft\DirectX','Version', DXVersion);
		//if (DXVersion = '4.09.00.0904') then begin
		//	Result := False;
		//end
		//else begin
		//	Result := True;
		//end;

	//end

	// DX has multiple components that don't always get installed
	// Web installer should always run b/c of this and to check for updates
	Result := True;

end;


// Install XNA?
function NeedXNA(): Boolean;

begin
	// Check registry to see if .Net 2.0 is installed
	if RegKeyExists(HKEY_LOCAL_MACHINE, 'SOFTWARE\Microsoft\XNA\Framework\v1.0') then begin
		Result := False;
	end
	else begin
		Result := True;
	end;
end;